home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
EnigmA Amiga Run 1996 February
/
EnigmA AMIGA RUN 04 (1996)(G.R. Edizioni)(IT)[!][issue 1996-02][Skylink CD III].iso
/
earcd
/
comm2
/
zpont311.lha
/
zpoint-3.11
/
Rexx
/
Anon.zprx
< prev
next >
Wrap
Text File
|
1995-08-21
|
7KB
|
228 lines
/*
$VER: Anon.zprx 1.2 (19.8.95) Copyright 1995 (c) Nils Görs.
Funktionsbeschreibung:
Dieses Skript wurde erstellt, um ganz bequem eine Nachricht über
den Anon-Server zu versenden.
Benutzung:
Schreiben bzw. kommentieren sie eine Nachricht wie bisher. Nun
können Sie die Nachricht "Versenden" oder "Speichern".
Wenn Sie "Versenden" gewählt haben sollten, dann müssen Sie sich
in das Spool-Brett begeben und von dort "Anon.zprx" aufrufen.
Falls Sie "Speicher" gewählt haben sollten, dann können Sie im
Brett bleiben und rufen dort "Anon.zprx" auf. Die alte Nachricht
wird hierbei kommentarlos aus dem SPOOL-Brett gelöscht.
"Anon.zprx", speichert die neue Nachricht auch im aktuellen Brett.
Installation:
Kopieren sie dieses Skript in das Rexx-Verzeichnis von ZP und
fügen sie danach der Datei 'fkeys.zp' auf Wunsch den Eintrag
"F1:SYS:Rexxc/RX ZPOINT:Rexx/Anon.zprx %s" hinzu.
Alternativ hierzu können Sie auch folgende Zeilen in die Datei
usermenus.zp einfügen:
*Versand via Anon
SYS:Rexxc/RX Zodiac:Rexx/Anon.zprx %s
Copyright:
Sie dürfen dieses Skript beliebig kopieren, solange es zusammen
mit Zodiac's Point eingesetzt wird, aber verändern Sie es bitte
nicht ohne Erlaubnis des Autors.
Autor dieses Skripts:
Nils Görs Tel. : +49 (0)202 784258
Kaiserstr. 97a EMail: N.Goers@Art-Line.Art-Line.de
42329 Wuppertal oder über das ZP-Support-Brett.
Verwenden Sie bitte nach Möglichkeit elektronische Post!
*/
/* Wie lautet die Adresse von Anon? */
AnonAdresse = "anon@anon.penet.fi"
/* und wie lautet Ihr Passwort? */
AnonPasswort = "mein Anon-Passwort"
/* soll die Originalnachricht entfernt werden?
0 = mit Sicherheitsabfrage
1 = ohne Sicherheitsabfrage */
DelImmer = 0
/* Name Ihrer privaten Adresse (OHNE Domain) ? */
MeinName = "N.Goers@"
/* ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
* Bitte geben Sie hier ihre Präferenzen ein ! *
*******************************************************************/
/*******************************************************************
* Bitte unterhalb dieser Zeile nichts mehr verändern! *
*******************************************************************/
wopts = ''
Datei.tmp = "t:anon.tmp"
NL = '0a'x
None = "-NONE-"
Bezug = "BEZ"
Crypto = "CRYPT"
Diskussion = "Diskussion-in"
Empfangsbest = "EB"
PGPSignatur = "PGP-SIG"
OPTIONS RESULTS
/* ------ von welchem ZP Port wurde das Script aufgerufen ? ------ */
PARSE ARG zpPort
IF zpPort == "" THEN
zpPort = "ZPoint"
ADDRESS VALUE zpPort
'GUILOCK text="Bitte etwas Geduld..."'
/* --- Dieses Skript darf nur im Brett ausgeführt werden --- */
WHICHLEVEL
IF Result ~= "BOARD" then DO
REQUESTNOTIFY "Bitte begeben Sie sich in ein Brett!"
EXIT
END
SERVER
ServerName=RESULT
BOARDINFO LABEL; Brettname=Result
IF INDEX(Brettname,'(Spool') == 0 THEN DO
MESSAGEINFO RECEIVER
IF (RESULT = AnonAdresse) THEN DO
REQUESTNOTIFY "Diese Nachricht wird schon via" AnonAdresse "versendet!"
EXIT
END
MESSAGEINFO ID
oldID = RESULT
wopts = wopts 'SAVE'
END
origName = UPPER(MeinName||servername)
MESSAGEINFO RECEIVER
Receivername=RESULT
Receivername2 = UPPER(Receivername)
IF ABBREV(Receivername2,origName) THEN
DO
MESSAGEINFO AUTHOR
ReceiverName=RESULT
Receivername2 = UPPER(Receivername)
IF ABBREV(Receivername2,origName) THEN
DO
requestnotify "Wieso wollen Sie eine anonyme",
NL"Nachricht an Ihre eigene Adresse senden ??"
EXIT
END
END
IF (ReceiverName = AnonAdresse) THEN DO
REQUESTNOTIFY "Diese Nachricht wird schon via" AnonAdresse "versendet!"
EXIT
END
/* jetzt scheint alles klar zu sein und die Originalnachricht
wird aus dem SPOOL-Brett entfernt ! */
CALL _DeleteMessInSpool
JUMPTOMESSAGE 'ID' oldID
IF (RC) == 0 THEN DO
REQUESTNOTIFY "Wo ist denn die Originalnachricht geblieben?"
EXIT
END
/* Welche Parameter enthält die Originalnachricht ?? */
MESSAGEINFO FULLSUBJECT
SubjectName=RESULT
FINDHEADER Crypto
IF RESULT ~= None THEN
DO
requestnotify "MITTEILUNG: Hallo lieber Anwender,",
NL"bisher habe ich noch keine PGP/QCP",
NL"Unterstützung eingebaut. Falls Sie",
NL"aber eine solche Unterstützung be-",
NL"nötigen, dann setzen Sie sich doch",
NL"bitte mit mir in Verbindung. "
/*
Ich persönlich sehe keinen Sinn darin Nachrichten PGP zu kodieren,
die man anonym versendet. Sehen Sie es anders ??
*/
EXIT
END
FINDHEADER Empfangsbest
IF RESULT ~= None THEN wopts = wopts 'CONFIRM'
FINDHEADER Diskussion
IF RESULT ~= None THEN wopts = wopts 'FOLLOWUP' '"'RESULT'"'
FINDHEADER ALL Bezug
IF RESULT ~= None THEN wopts = wopts 'REFERENCES' '"'RESULT'"'
MESSAGEINFO TYPE
IF RESULT == "BINARY" THEN wopts = wopts 'BINARY'
IF ~OPEN(Dat,Datei.tmp||zpPort,"Write") THEN
DO
REQUESTNOTIFY "Ich konnte die Datei" Datei.tmp||zpPort "nicht zum schreiben öffnen!"
EXIT
END
CALL WRITELN(Dat,"X-Anon-To:" Receivername)
CALL WRITELN(Dat,"X-Anon-Password:" AnonPasswort)
CALL CLOSE(Dat)
SAVEMESSAGEBODY Datei.tmp||zpPort
WRITEMESSAGE Datei.tmp||zpPort,
'RECEIVER' AnonAdresse,
'SUBJECT' '"'SubjectName'"',
wopts
IF RESULT = '' THEN DO /* Hups! Fehler! */
REQUESTNOTIFY "Konnte Nachricht nicht verschicken!"
CALL _DeleteTemps
END
IF DelImmer == 0 THEN /* Soll nachgefragt werden? */
DO /* Soll die Nachricht gelöscht werden ? */
REQUESTRESPONSE "Soll die Ursprungsnachricht gelöscht werden?"
DelImmer = RC
END
IF DelImmer = 1 THEN DELETE ONE /* Wenn 1, dann Nachricht löschen! */
/************************************
* im Speicher alles wieder löschen *
* und das Skript beenden! *
************************************/
_DeleteTemps:
ADDRESS COMMAND 'delete' Datei.tmp||zpPort '>NIL:'
GUILOCK off /* Die GUI wieder freigeben! */
EXIT
/***************************************************
* diese Routine ist dafür zuständig, daß die alte *
* Nachricht aus dem Spool-Brett entfernt wird! *
***************************************************/
_DeleteMessInSpool:
BOARDMENU
JUMPTOBOARD 1
ENTERBOARD
JUMPTOMESSAGE 'ID' oldID
IF (RC) == 1 THEN DELETE ONE
BOARDMENU
JUMPTOBOARD 'NAME' BrettName
ENTERBOARD
RETURN
/*EOS*/